上一页 | 目录 | 下一页

5.2 预定义

你可以使用这些标准预定义自动向开发版本的标题添加构建时间,以及向版本号添加日期,等等。

5.2.1 ${__FILE__}

当前脚本名称。

5.2.2 ${__LINE__}

当前行号。

5.2.3 ${__DATE__}

当脚本开始编译时当前时区的日期。

5.2.4 ${__TIME__}

当脚本开始编译时当前时区的时间。

5.2.5 ${__TIMESTAMP__}

当脚本开始编译时脚本的修改时间戳。

5.2.6 范围预定义

包含当前代码范围信息的标准预定义。

5.2.6.1 ${__GLOBAL__}

在全局范围内定义。

Section test

  !ifdef ${__GLOBAL__}
    !error "这不应该在这里!"
  !endif

SectionEnd

Function test

  !ifdef ${__GLOBAL__}
    !error "这不应该在这里!"
  !endif

FunctionEnd

PageEx instfiles

  !ifdef ${__GLOBAL__}
    !error "这不应该在这里!"
  !endif

PageExEnd

5.2.6.2 ${__SECTION__}

区段 范围内,被定义为没有任何前缀的区段名。

!ifdef __SECTION__
  !error "这不应该在这里!"
!endif

Section test

  !ifndef __SECTION__
    !error "缺少预定义!"
  !endif

  !if ${__SECTION__} != test
    !error "预定义值错误!"
  !endif

SectionEnd

Section !test

  !if ${__SECTION__} != test
    !error "预定义值错误!"
  !endif

SectionEnd

Section un.test

  !if ${__SECTION__} != test
    !error "预定义值错误!"
  !endif

SectionEnd

5.2.6.3 ${__FUNCTION__}

函数 范围内,被定义为没有任何前缀的函数名。

!ifdef __FUNCTION__
  !error "这不应该在这里!"
!endif

Function test

  !ifndef __FUNCTION__
    !error "缺少预定义!"
  !endif

  !if ${__FUNCTION__} != test
    !error "预定义值错误!"
  !endif

FunctionEnd

Function un.test

  !if ${__FUNCTION__} != test
    !error "预定义值错误!"
  !endif

FunctionEnd

5.2.6.4 ${__PAGEEX__}

PageEx 范围内,被定义为页面类型。

!ifdef __PAGEEX__
  !error "这不应该在这里!"
!endif

PageEx instfiles

  !ifndef __PAGEEX__
    !error "缺少预定义!"
  !endif

  !if ${__PAGEEX__} != instfiles
    !error "页面类型错误"
  !endif

PageExEnd

5.2.6.5 ${__UNINSTALL__}

卸载程序中被定义为 区段, 函数PageEx 范围。

!ifdef __UNINSTALL__
  !error "这不应该在这里!"
!endif

Function test

  !ifdef __UNINSTALL__
    !error "这不应该在这里!"
  !endif

FunctionEnd

Function un.test

  !ifndef __UNINSTALL__
    !error "缺少预定义!" 
  !endif

FunctionEnd

上一页 | 目录 | 下一页