NSIS打包Mysql、JDK、tomcat后，exe双击很慢

wjl

NSIS打包Mysql、JDK、tomcat后，exe文件有370M,什么原因会导致。exe打开很慢，双击后需要3分钟左右才能弹出安装界面。nsi文件如下，求大神帮忙看看哪里的问题。
; Script generated by the HM NIS Edit Script Wizard.

; HM NIS Edit Wizard helper defines
!define PRODUCT_NAME "web系统"
!define PRODUCT_VERSION "1.0"
!define PRODUCT_PUBLISHER "wangxl"
!define PRODUCT_WEB_SITE "http://localhost:8080/webapp"
!define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\appletviewer.exe"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"

; 定义系统环境变量的 注册表key值
!define WriteEnvStr_RegKey 'HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment"'

; MUI 1.67 compatible ------
!include "MUI.nsh"

; MUI Settings
!define MUI_ABORTWARNING
!define MUI_WELCOMEPAGE_TITLE "\r\n ${PRODUCT_NAME} ${PRODUCT_VERSION}版"
!define MUI_WELCOMEPAGE_TEXT "     欢迎使用${PRODUCT_NAME} 。 \r\n\r\n 软件制作： \r\n\r\n $_CLICK"

; Welcome page
!insertmacro MUI_PAGE_WELCOME
; Directory page
!insertmacro MUI_PAGE_DIRECTORY
; Instfiles page
!insertmacro MUI_PAGE_INSTFILES
; Finish page
!insertmacro MUI_PAGE_FINISH

; Uninstaller pages
!insertmacro MUI_UNPAGE_INSTFILES

; Language files
!insertmacro MUI_LANGUAGE "SimpChinese"

!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS

; MUI end ------

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "${PRODUCT_NAME}_${PRODUCT_VERSION}.exe"
InstallDir "$PROGRAMFILES\bmj"
ShowInstDetails show
ShowUnInstDetails show
BrandingText "软件制作："


Section "JDK1.7" SEC01
  sectionin 1
  sectionin RO
  SetOutPath "$INSTDIR\JDK1.7"
  SetOverwrite try
  File /r "F:\wjl\dabao\oldbak2\SecurityClassificationSystem64\jdk\*.*"
SectionEnd

Section "tomcat7" SEC02
  sectionin 1
  sectionin RO
  SetOutPath "$INSTDIR\tomcat7"
  SetOverwrite try
  File /r "F:\apache-tomcat-7.0.81\*.*"
SectionEnd


Section "mysql5.6" SEC03
  sectionin 1
  sectionin RO
  SetOutPath "$INSTDIR\mysql"
  SetOverwrite try
  File /r "F:\wjl\dabao\oldbak2\SecurityClassificationSystem64\mysql\*.*"
SectionEnd

Section -AdditionalIcons
  SetOutPath $INSTDIR
  #安装服务
  call regExpandStr
  call installService
  call startService
  WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
  CreateShortCut "$SMPROGRAMS\zhldxtweb\${PRODUCT_NAME}.lnk" "$INSTDIR\${PRODUCT_NAME}.url"
  CreateShortCut "$SMPROGRAMS\zhldxtweb\Uninstall.lnk" "$INSTDIR\uninst.exe"
SectionEnd

Section -Post
  WriteUninstaller "$INSTDIR\uninst.exe"
  WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\jdk1.7\bin\appletviewer.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\jdk1.7\bin\appletviewer.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
SectionEnd

;设置环境变量
Function "regExpandStr"
  SetOverwrite ifnewer
  ;设置jdk环境变量
  WriteRegExpandStr ${WriteEnvStr_RegKey} "JAVA_HOME" "$INSTDIR\jdk1.7"
  ;设置catalina_home
  WriteRegExpandStr ${WriteEnvStr_RegKey} "CATALINA_HOME" "$INSTDIR\tomcat7"
  #第一次是使环境变量修改对其他进程有效;刷新环境变量
  SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000
  SetOverwrite on
functionend

;注册服务
Function "installService"
  detailprint "install mysql Service..."
  SetOutPath "$INSTDIR\mysql\bin"
  nsExec::Exec 'cmd /c mysqld install MySQL5.6'
  detailprint "install mysql Service success..."
  Sleep 2000
  detailprint "install tomcat Service..."
  SetOutPath "$INSTDIR\tomcat7\bin"
  nsExec::Exec 'cmd /c service install tomcat7'
  nsExec::Exec 'cmd /c sc config tomcat7 start= auto'
  detailprint "install tomcat Service success..."
  Sleep 2000
functionend

; 启动服务
Function "startService"
  detailprint "start mysql..."
  nsExec::Exec 'cmd /c sc start MySQL5.6'
  detailprint "start MySQL5.1 success..."
  detailprint "start tomcat..."
  nsExec::Exec 'cmd /c sc start tomcat7'
  detailprint "start tomcat success..."
functionend

;停止服务
Function "un.stopService"
  detailprint "正在停止tomcat服务......."
  nsExec::Exec 'cmd /c sc stop tomcat7'
  detailprint "停止tomcat服务成功......."
  detailprint "正在停止mysql服务......."
  nsExec::Exec 'cmd /c sc stop MySQL5.6'
  detailprint "停止mysql服务成功......."
functionend

;删除服务
Function "un.uninstService"
  detailprint "正在卸载tomcat服务......."
  nsExec::Exec 'cmd /c sc delete tomcat7'
  detailprint "卸载tomcat服务成功......."
  detailprint "正在卸载mysql服务......."
  nsExec::Exec 'cmd /c sc delete MySQL5.6'
  detailprint "卸载mysql服务成功......."
functionend

;清空环境变量
Function "un.emptyRegExpandStr"
  #删除 系统环境变量JAVA_HOME 和 CATALINA_HOME
  #卸载的时候必须设置JAVA_HOME 和 CATALINA_HOME两个环境系统变量为空，或者删除这两个系统变量。否则会出现NSIS选择系统变量的错误（NSIS会自动选择之前有值的系统变量，而不是选择当前刚设置的系统变量）
  detailprint "正在删除相关环境变量......."
  WriteRegExpandStr ${WriteEnvStr_RegKey} "JAVA_HOME" ""
  sleep 1000
  ;设置TOMCAT环境变量CATALINA_HOME
  WriteRegExpandStr ${WriteEnvStr_RegKey} "CATALINA_HOME" ""
functionend

Function un.onUninstSuccess
  HideWindow
  MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) 已成功地从你的计算机移除。"
FunctionEnd

Function un.onInit
  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "你确实要完全移除 $(^Name) ，其及所有的组件？" IDYES +2
  Abort
FunctionEnd

Section Uninstall
  #开始停止/卸载服务
  call un.stopService
  call un.uninstService
  call un.emptyRegExpandStr
  #删除所有安装目录文件
  detailprint "正在删除安装目录......."
  Delete "$INSTDIR\${PRODUCT_NAME}.url"
  Delete "$INSTDIR\uninst.exe"
  Delete "$SMPROGRAMS\zhldxtweb\*.*"
  Delete "$DESKTOP\${PRODUCT_NAME}.url"
  RMDir "$SMPROGRAMS\zhldxtweb"
  RMDir /r "$INSTDIR\JDK1.7"
  RMDir /r "$INSTDIR\tomcat7"
  RMDir /r "$INSTDIR\mysql"
  RMDir /r "$INSTDIR\doc"
  RMDir /r "$INSTDIR"
  DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
  DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
  SetAutoClose true
SectionEnd

flighty

是不是压缩的问题？
SetCompressor lzma
还有，看看你在.onInit里干了什么？

wjl

不是NSIS慢，是我的WIN7慢，在xp和window server2008打开很快。崩溃啊。。。